Sample Scripts from GB Books
GB003:  2次元における電導

今度はプレートの形状を台形に変えて電流の流れを調べてみましょう。この場合、解析的な手法で厳密解を求めることはできないので数値解に頼らざるを得ません。境界条件は前の例と同様、上辺で U = 1、下辺で U = 0、両側の斜辺は絶縁境界であるとします。

基本形は一つ前の econduction01a.pde と変りません。
  TITLE
    'Conduction in a Trapezoidal Plate'    { econduction01b.pde }

  SELECT
    Errlim = 3e-5

  VARIABLES
    U                     { Electric potential }

  DEFINITIONS
    L1 = 0.5  L2 = 0.25  Ly = 1.0
    cond = 5.99e7         { Conductivity of Cu }
    Ex = -dx(U)  Ey = -dy(U)  E = -grad(U)  Em = magnitude(E)
    Jx = cond*Ex  Jy = cond*Ey  J = cond*E  Jm = magnitude(J) 
                          { Electrical current density }

  EQUATIONS
    div(J)=0              { 2nd order PDE in U }

  BOUNDARIES
    Region 1
      Start(-L1, 0)
        Value(U) = 0    Line to (L1, 0)
        Natural(U) = 0  Line to (L2, Ly)   { Insulated }
        Value(U) = 1.0  Line to (-L2, Ly)
        Natural(U) = 0  Line to Close      { Insulated }

  PLOTS
    Grid(x, y)
    Contour(U)    Surface(U)
    Vector(E) norm
    Contour(Jx)    Contour(Jy)    Contour(Jm)

  END

(1) Grid(x, y)
FlexPDEによって自動生成されるメッシュはプレートの4隅の部分で密度の高いものとなっています。

(2) Contour(U)
解析対象領域（ドメイン）上での関数 U(x, y) の等高線図、すなわち等電位線は次のようになります。上下の境界上で U の値が指定値となっていることが確認できます。なお、等高線がすべて斜辺と直交している点にご注意ください。これは絶縁境界上で U の法線微分が0という条件からもたらされる帰結でもあります。

(3) Surface(U)
関数 U(x, y) の曲面の形状をプロットしたものです。

(4) Vector(E) norm
電場ベクトル E のベクトルプロットを示したものです。normという指定があるため、ベクトル長は一律となっています。斜辺に沿った部分ではベクトルが斜辺に平行となっている点に注意してください。

(5) Contour(Jx)
電流密度ベクトル J のx成分の値に関する等高線図です。上辺から入った電流は徐々に左右に広がって行くため、Jxの値は矩形プレートの場合と異なり0とはなりません。

(6) Contour(Jy)
電流密度ベクトル J のy成分の値に関する等高線図です。

(7) Contour(Jm)
電流密度ベクトル J の絶対値に関する等高線図です。上の角においてJmの値は最も大きくなっています。(2)の U の等高線図よりわかることですが、上辺に近い部分での水平に近い等高線は斜辺の近傍でそれに直交するよう向きを変えることになります。このため上の角の近くでは U の等高線が込み合った形となり、その結果として勾配がきつくなるわけです。