サンプルスクリプト
[3-1] 3D平行板コンデンサ【3D_Capacitor.pde】

1. 概要

１枚の誘電体で隔てられ、サイズの異なる２枚の金属帯で構成したコンデンサを示します。

2. メッシュ図

5×5(mm)で厚さ１(mm)の誘電体の上下に、厚さ 0.1(mm)の金属帯を配置します。

• 上側金属帯：幅 1(mm)，厚 0.1(mm)，Y＝1～5(mm)，V=1メッシュ図（下図）では隠れて見えません

• 下側金属帯：幅 3(mm)，厚 0.1(mm)，Y＝0～4(mm)，V=0メッシュ図（下図）手前の空色部分

解析領域の外周は、絶縁境界です。

 

 

3. 解析結果

図中の {Fig.A}，{Fig.B} は、それぞれの図と対応し、更に４項で対応するスクリプトを示します。

 

 

4. スクリプト

下記のスクリプトをマウスでコピーし、FlexPDEエディット･ウィンドウに貼り付けて実行する際には、日本語のコメントを除去して下さい。 そのままですと、コンパイル･エラーが発生する場合があります｡

{  3D_CAPACITOR.PDE

  This problem is an extension of "3D_Extrusion_Spec.PDE", and shows
  a capacitor formed by two metal strips of different size separated
  by a sheet of dielectric.

}

TITLE '3D Capacitor'

COORDINATES
  CARTESIAN3

SELECT
  alias(x) = "X(mm)"    { rename the axes }
  alias(y) = "Y(mm)"
  alias(z) = "Z(mm)"
  PAINTED               { paint all contours }

VARIABLES
  V

DEFINITIONS
  Kdiel= 6
  Kmetal=1e6
  Kair=1
  K = Kair  { default K to Kair - this will change in some layers/regions デフォルト値 }
  V0 = 0
  V1 = 1
  Eps0 = 8.854e-12                      { Farads/M 真空の誘電率}
  Eps0mm = 0.001*Eps0                   { Farads/mm }
  W = integral(0.5*K*eps0mm*grad(V)^2)  { Stored Energy }
  C = 1.0e6*2*W/(V1-V0)^2               { Capacitance in microFarads 静電容量 }

EQUATIONS
  V : DIV(K*GRAD(V)) = 0

EXTRUSION
  SURFACE   "Bottom"                    Z=0
    LAYER   "Bottom Air"
  SURFACE   "Bottom Air - Metal"        Z=0.9
    LAYER   "Bottom Metal"
  SURFACE   "Bottom Metal - Dielectric" Z=1
    LAYER   "Dielectric"
  SURFACE   "Top Metal - Dielectric"    Z=2
    LAYER   "Top Metal"
  SURFACE   "Top Metal - Air"           Z=2.1
    LAYER   "Top Air"
  SURFACE   "Top"                       Z=3

BOUNDARIES
  SURFACE "Bottom" NATURAL(V)=0  { Insulators top and bottom 解析領域の上･下面は絶縁境界です }
  SURFACE "Top"    NATURAL(V)=0

  REGION 1  { this is the outer boundary of the system }
      LAYER "dielectric" K = Kdiel  { all other layers default to Kair K値を指定しない部分は全て Kair値 }
      START(0,0)
      LINE TO (5,0)  TO (5,5)  TO(0,5)  to close

   LIMITED REGION 2 { the larger bottom plate }
      LAYER "Bottom Metal" K = Kmetal
      START(1,0)
      LAYER "Bottom Metal" VALUE(V)=V0
      LINE TO (4,0)
      LAYER "Bottom Metal" NATURAL(V)=0
      Line TO (4,4) TO (1,4) to close

   LIMITED REGION 3 { the smaller top plate}
      LAYER "Top Metal" K = Kmetal
      START(2,1)
      LINE TO (3,1) TO (3,5)
      LAYER "Top Metal" VALUE(V)=V1
      LINE TO (2,5)
      LAYER "Top Metal" NATURAL(V)=0
      LINE to close

MONITORS
  CONTOUR(V) ON Y=2.5

PLOTS
  GRID(X,Z)  ON Y=2.5
  CONTOUR(V) ON X=2.5 REPORT(C) as "Capacitance(uF)"	{Fig.A}
  CONTOUR(V) ON Y=2.5 REPORT(C) as "Capacitance(uF)"	{Fig.B}
  CONTOUR(V) ON Z=1.5 REPORT(C) as "Capacitance(uF)"
  CONTOUR(1/K) ON Y=2.5 as "Material"

END