サンプルスクリプト
[8-1] 長円形磁石周辺の磁場解析 【3D_Magnetron.pde】

1. 概要

長円形磁石周辺の３次元磁場解析です。このモデルの方程式につきましては、｢FlexPDE 7 ユーザ･マニュアル p.229｣ に記載しております。なお下記のURLは、２次元磁場解析についてですが、内容的に関連します。
http://lightstone.co.jp/flexpde/backstrom/gb008a.htm

2. メッシュ図

解析領域の全体メッシュ図を [Fig.A]、磁性体磁石部分を [Fig.B]、[Fig.B] 図中に青色枠線で示します部分の断面メッシュ図を {Fig.C} に示します。
 {Fig.C} は、４項で対応するスクリプトを示します。
 [Fig.A] は、４項に示しますスクリプトを実行すると自動的に作成されます。
 解析領域全体のメッシュ図は、FlexPDEが自動的に作成します。
[Fig.B] は、FlexPDE の出力ではありません。　弊社取り扱い製品の Originで作図しました。

 

解析領域の全外周表面では、ベクトルポテンシャル A(x,y,z)=0、更に本ケースでは全解析領域で Az=0 とします。
透磁率　・空気：1.0
              ・Magnet, Inner Magnet：1.0
              ・Magnet Plate：1000
永久磁石の強さ　・Magnet：10000
                        ・Inner Magnet：-10000

3. 解析結果

ベクトルポテンシャルＡのｘ，ｙ成分の等高線図をそれぞれ {Fig.D}、{Fig.E} に示します。
磁気誘導ベクトルＢの y-z成分，x-z成分のベクトル図をそれぞれ {Fig.F}、{Fig.G} に示します。
{Fig.D}～{Fig.G} は、４項で対応するスクリプトを示します。

4. スクリプト

下記のスクリプトをマウスでコピーし、FlexPDE エディット･ウィンドウに貼り付けて実行する際は、日本語のコメントを除去して下さい｡ そのままですと、コンパイル･エラーが発生する場合があります｡

{ 3D_MAGNETRON.PDE

  MODEL OF A GENERIC MAGNETRON IN 3D

  The development of this model is described in the Magnetostatics chapter of the
  Electromagnetic Applications section of the FlexPDE User Manual (p.229 V6).

}

TITLE 'Oval Magnet'

COORDINATES
  CARTESIAN3

SELECT
  ngrid=25
  alias(x) = "X(cm)"
  alias(y) = "Y(cm)"
  alias(z) = "Z(cm)"

VARIABLES
  Ax,Ay    { assume Az is zero! }

DEFINITIONS
  MuMag=1.0  ! Permeabilities：透磁率
  MuAir=1.0
  MuSST=1000
  MuTarget=1.0
  Mu=MuAir  ! default to Air

  MzMag = 10000   ! permanent magnet strength：永久磁石の強さ

  Mz = 0        ! global magnetization variable：磁化のグローバル変数
  Nx = vector(0,Mz,0)
  Ny = vector(-Mz,0,0)

  B = curl(Ax,Ay,0)  ! magnetic induction vector：磁気誘導ベクトル
  Bxx= -dz(Ay)
  Byy= dz(Ax)  ! unfortunately, "By" is a reserved word.
  Bzz= dx(Ay)-dy(Ax)

EQUATIONS
  Ax:   div(grad(Ax)/mu+Nx) = 0
  Ay:   div(grad(Ay)/mu+Ny) = 0

EXTRUSION
   SURFACE "Boundary Bottom"     Z=-5
   SURFACE "Magnet Plate Bottom"    Z=0
     LAYER "Magnet Plate"
   SURFACE "Magnet Plate Top"    Z=1
     LAYER "Magnet"
   SURFACE "Magnet Top"      Z=2
   SURFACE "Boundary Top"     Z=8

BOUNDARIES
  Surface "boundary bottom" value (Ax)=0  value(Ay)=0
  Surface "boundary top" value (Ax)=0 value(Ay)=0

  REGION 1     {Air bounded by conductive box 解析領域の外周：Ax=0, Ay=0 }
      START (20,-10)
      value(Ax)=0  value(Ay)=0
      arc(center=20,0) ANGLE=180
      Line TO (-20,10)
      arc(center=-20,0) ANGLE=180
        LINE TO CLOSE

  LIMITED REGION 2     { Magnet Plate }
      LAYER "Magnet Plate" Mu=MuSST
      LAYER "Magnet" Mu=MuMag  Mz = MzMag
      START (20,-8)
        ARC(center=20,0) ANGLE=180
        LINE TO (-20,8)
        ARC(center=-20,0) ANGLE=180
        LINE TO CLOSE

    LIMITED REGION 3     { Inner Gap  }
      LAYER "Magnet"	{ Muの指定がないのでデフォルトMuAirが適用されます }
      START (20,-6)
        ARC(center=20,0) ANGLE=180
        LINE TO (-20,6)
        ARC(center=-20,0) ANGLE=180
        LINE TO CLOSE

    LIMITED REGION 4     {Inner Magnet }
      LAYER "Magnet" Mu=MuMag  Mz = -MzMag
      START (20,-2)
        ARC(center=20,0) ANGLE=180
        LINE TO (-20,2)
        ARC(center=-20,0) ANGLE=180
        LINE TO CLOSE

MONITORS
  grid(y,z) on x=0
  grid(x,z) on  y=0
  grid(x,y) on  z=1.01
  contour(Ax) on x=0
  contour(Ay) on y=0

PLOTS
  grid(y,z) on x=0			{Fig.C}
  grid(x,z) on y=0
  grid(x,y) on z=1.01
  contour(Ax) on x=0			{Fig.D}
  contour(Ay) on y=0			{Fig.E}
  vector(Bxx,Byy) on z=2.01 norm
  vector(Byy,Bzz) on x=0 norm		{Fig.F}
  vector(Bxx,Bzz) on y=4 norm		{Fig.G}
  contour(magnitude(Bxx,Byy,Bzz)) on z=2

END