Sample Scripts from GB Books
GB008:  2次元静磁場

ここでは右図のような棒磁石のまわりの磁場について調べることにします。棒磁石の幅は0.1m、 長さは0.2mとし、y軸方向に磁化されているものとします。棒磁石の両端において B_y の値は一定（+0.1, -0.1）、側面においては B_x = 0 という境界条件を想定します。ただし数式(6)、すなわち

を考慮するなら、境界上で

と指定することで上記境界条件が表現されることがわかります。

magnetics01a.pde をベースにスクリプトを用意します。
  TITLE
    'Field around a Permanent Magnet'    { magnetics01d.pde }

  SELECT
    Errlim = 3e-4

  VARIABLES
    Az                       { Magnetic vector potential }

偏微分方程式の定義に先立ち、パラメータ類をSI単位系で定義します。
  DEFINITIONS                { SI units }
    L = 1.0  L0 = 0.05
    mu0 = 4*PI*1e-7          { Permeability of vacuum }
    mu = mu0                 { Permeability }
    Jz = 0                   { Current density }
    B0 = 0.1                 { Magnetic induction }
    B_x = dy(Az)  B_y = -dx(Az)
    B = Vector(B_x, B_y)  Bm = magnitude(B)
                             { Magnetic flux density }
    Hx = B_x/mu  Hy = B_y/mu  H = B/mu  Hm = Bm/mu
                             { Magnetic field strength }

  EQUATIONS
    dx(Hy) - dy(Hx) = Jz     { 2nd order PDE in Az }

境界の形状と境界条件を定義します。なお、磁石内部は解析対象ドメインから除外します。また外部境界上では Az = 0 という条件を設定します。
  BOUNDARIES
    Region 1
      Start 'outer' (-L, -L) Value(Az) = 0
        Line to (L, -L) to (L, L) to (-L, L) to Close

      Start 'magnet' (-L0, -2*L0)  { Exclude }
        Value(Az) = -B0*x
        Line to (L0, -2*L0) to (L0, 2*L0) to (-L0, 2*L0) to Close

最後に出力すべき情報を規定します。
  PLOTS
    Grid(x, y)
    Elevation(Az) on 'magnet'  { Verify Az on inner boundary }
    Elevation(normal(B)) on 'magnet'
    Contour(Bm) log
    Contour(Bm) painted zoom(-5*L0, -5*L0, 10*L0, 10*L0)
    Surface(Bm) zoom(-5*L0, -5*L0, 10*L0, 10*L0)
    Vector(B) norm
    Vector(B) norm zoom(-5*L0, -5*L0, 10*L0, 10*L0)

  END

(1) Grid(x, y)
FlexPDEによって生成されたメッシュ構成を示しています。メッシュ再構成は4回行われ 、磁石周辺のメッシュ密度がかなり細かいものになっていることがわかります。

(2) Elevation(Az) on 'magnet'
棒磁石の境界上で Az の値が企図した設定値になっているかどうかをチェックするためのelevationプロットです。

(3) Elevation(normal(B)) on 'magnet'
磁石境界線上で磁束密度ベクトル B の法線成分の値をプロットしたものです。企図した通りの設定となっていることがわかります。

(4) Contour(Bm) log
磁束密度ベクトル B の絶対値に関する等高線を対数スケールでプロットしたものです。

(5) Contour(Bm) painted zoom(-5*L0, -5*L0, 10*L0, 10*L0)
磁束密度ベクトル B の絶対値に関する等高線プロットのうち、磁石の近傍部分のみを拡大して示したものです。

(6) Surface(Bm) zoom(-5*L0, -5*L0, 10*L0, 10*L0)
プロット(5)と同じ内容ですが、曲面図の形で表示したものです。磁石の4隅におけるピークの存在が明確に示されています。

(7) Vector(B) norm
磁束密度ベクトル B のベクトル場をプロットしたものです。外周上で Az = 0 という条件を設定しているため、外周上での法線成分 Bn は0となっています（gb008a参照）。

(8) Vector(B) norm zoom(-5*L0, -5*L0, 10*L0, 10*L0)
プロット(7)のベクトル場のうち、磁石近傍のみを拡大表示したものです。