Stata グラフギャラリー　基本のグラフ

*サンプルデータを読み込み
use https://www.stata-press.com/data/r17/uslifeexp2, clear
*y変数をle、x変数をyearとして散布図を描画
scatter le year

コピー

*サンプルデータを読み込み
webuse auto, clear
*y変数をmpgとheadroom、x変数をweightとして散布図を描画
scatter mpg headroom weight

コピー

*サンプルデータを読み込み
webuse auto, clear
*y変数をmpgとheadroomとturn、x変数をweightとして散布図を描画
scatter mpg headroom turn weight

コピー

*サンプルデータを読み込み
webuse auto, clear
*y変数をmpg、x変数をweight、マーカーラベル変数をmakeとして散布図を描画（観測値の範囲は1～15行目）
scatter mpg weight in 1/15, mlabel(make)

コピー

*サンプルデータを読み込み
use https://www.stata-press.com/data/r17/census, clear
*既存の変数divorceとpop18pから新規変数drateを作成
generate drate = divorce / pop18p
*変数drateにラベルを付加
label var drate "Divorce rate"
*y変数をdrate、x変数をmedage、重みをpop18pとして、stateがNevadaでないデータについて散布図を描画（マーカーシンボルは白抜きの丸、note付加）
scatter drate medage [w=pop18p] if state!="Nevada", msymbol(Oh)  note("State data excluding Nevada" "Area of symbol proportional to state's population aged 18+")

コピー

*サンプルデータを読み込み
use https://www.stata-press.com/data/r17/autornd, clear
*y変数をmpg、x変数をweightとして散布図を描画（ジッターは7）
scatter mpg weight, jitter(7)

コピー

*サンプルデータを読み込み
use https://www.stata-press.com/data/r17/uslifeexp, clear
*y変数をle、x変数をyearとして折れ線グラフを描画
line le year

コピー

*サンプルデータを読み込み
webuse uslifeexp, clear
*y変数をle_wmとle_bm、x変数をyearとして折れ線グラフを描画
line le_wm le_bm year, legend(size(small))

コピー

*サンプルデータを読み込み
webuse uslifeexp, clear
*y変数をleとle_maleとle_female、x変数をyearとして折れ線グラフを描画
line le le_male le_female year, legend(size(medsmall))

コピー

*サンプルデータを読み込み
use https://www.stata-press.com/data/r17/uslifeexp, clear
*既存の変数le_wmとle_bmから新規変数diffを作成
generate diff = le_wm - le_bm
*変数diffにラベルを付加
label variable diff "Difference"
*y変数をle_wmとle_bmとdiff、x変数をyearとして折れ線グラフを描画し、さらに変数diffにフィット線を追加
line le_wm year, yaxis(1 2) xaxis(1 2) || line le_bm year  || line diff year || lfit diff year ||, ylabel(0(5)20, axis(2) gmin angle(horizontal)) ylabel(0 20(10)80, gmax angle(horizontal)) ytitle("", axis(2)) xlabel(1918, axis(2)) xtitle("", axis(2)) ylabel(, axis(2) grid) ytitle("Life expectancy at birth (years)") title("White and black life expectancy") subtitle("USA, 1900-1999") note("Source: National Vital Statistics, Vol 50, No. 6" "(1918 dip caused by 1918 Influenza Pandemic)") legend(label(1 "White males") label(2 "Black males")) 

コピー

*サンプルデータを読み込み
webuse sp500, clear
*y変数をclose、x変数をdateとして接続線グラフを描画（観測値の範囲は1～15行目）
twoway connected close date in 1/15

コピー

*サンプルデータを読み込み
webuse sp500, clear
*y変数をhighとlow、x変数をdateとして接続線グラフを描画（観測値の範囲は1～15行目）
twoway connected high low date in 1/15

コピー

*サンプルデータを読み込み
webuse sp500, clear
*y変数をhighとlowとclose、x変数をdateとして接続線グラフを描画（観測値の範囲は1～15行目）
twoway connected high low close date in 1/15

コピー

*サンプルデータを読み込み
webuse sp500, clear
*y変数をhighとlow、x変数をdateとして範囲グラフを描画（観測値の範囲は1～15行目）
twoway rarea high low date in 1/15

コピー

*サンプルデータを読み込み
webuse sp500, clear
*y変数をhighとlow、x変数をdateとして棒の範囲グラフを描画（観測値の範囲は1～15行目）
twoway rbar high low date in 1/15

コピー

*サンプルデータを読み込み
webuse sp500, clear
*y変数をhighとlow、x変数をdateとしてキャップ付きスパイクの範囲グラフを描画（観測値の範囲は1～15行目）
twoway rcap high low date in 1/15

コピー

*サンプルデータを読み込み
webuse sp500, clear
*y変数をhighとlow、x変数をdateとしてマーカーシンボルキャップ付きの範囲グラフを描画（観測値の範囲は1～15行目）
twoway rcapsym high low date in 1/15

コピー

*サンプルデータを読み込み
webuse sp500, clear
*y変数をhighとlow、x変数をdateとして接続線の範囲グラフを描画（観測値の範囲は1～15行目）
twoway rconnected high low date in 1/15

コピー

*サンプルデータを読み込み
webuse sp500, clear
*y変数をhighとlow、x変数をdateとしてスパイクの範囲グラフを描画（観測値の範囲は1～15行目）
twoway rspike high low date in 1/15

コピー

*サンプルデータを読み込み
webuse gnp96, clear
*y変数をgnp96の階差、x変数をdateとして面グラフを描画
twoway area d.gnp96 date

コピー

*サンプルデータを読み込み
webuse sp500, clear
*y変数をhighとcloseとlow、x変数をdateとして面グラフを描画（観測値の範囲は1～15行目）
twoway area high close low date in 1/15

コピー

*サンプルデータを読み込み
webuse pop2000, clear
*y変数をmaletotal、x変数をagegrpとして水平方向の面グラフを描画
twoway area maletotal agegrp, horizontal

コピー

*サンプルデータを読み込み
use https://www.stata-press.com/data/r17/citytemp, clear
*変数divisionの値ごとに棒グラフを描画（パーセント）
graph bar, over(division)

コピー

*サンプルデータを読み込み
webuse sp500, clear
*y変数をchange、x変数をdateとして二元棒グラフを描画（観測値の範囲は1～57行目）
twoway bar change date in 1/57

コピー

*サンプルデータを読み込み
use https://www.stata-press.com/data/r17/citytemp, clear
*変数tempjulyとtempjanについて、変数regionの値ごとに棒グラフを描画
graph bar (mean) tempjuly tempjan, over(region) legend( label(1 "July") label(2 "January") ) ytitle("Degrees Fahrenheit") title("Average July and January temperatures") subtitle("by regions of the United States") note("Source: U.S. Census Bureau, U.S. Dept. of Commerce")

コピー

*サンプルデータを読み込み
webuse citytemp, clear
*変数tempjulyとtempjanについて、変数regionの値ごとに積み上げ棒グラフを描画
graph bar tempjan tempjuly, over(region) stack

コピー

*サンプルデータを読み込み
webuse sp500, clear
*y変数をhighとlow、x変数をdateとして積み上げ棒グラフを描画（観測値の範囲は1～15行目）
twoway bar high low date in 1/15

コピー

*サンプルデータを読み込み
webuse citytemp, clear
*変数heatddとcoolddについて、変数regionの値ごとにラベル付き棒グラフを描画
graph bar heatdd cooldd, over(region) blabel(total)

コピー

*サンプルデータを読み込み
webuse pop2000, clear
*変数maletotalを負の値に変換
replace maletotal = -maletotal
*y変数をmaletotalとfemtotal、x変数をagegrpとして水平方向の二元棒グラフを描画
twoway bar maletotal agegrp, horizontal || bar femtotal agegrp, horizontal

コピー

*サンプルデータを読み込み
use https://www.stata-press.com/data/r17/citytemp, clear
*変数tempjanについて、変数divisionとregionの値ごとに水平方向の棒グラフを描画
graph hbar (mean) tempjan, over(division) over(region) nofill ytitle("Degrees Fahrenheit") title("Average January temperature") subtitle("by region and division of the United States") note("Source: U.S. Census Bureau, U.S. Dept. of Commerce")

コピー

*サンプルデータを読み込み
use https://www.stata-press.com/data/r17/educ99gdp, clear
*変数privateとpublicから新規変数totalを作成
generate total = private + public
*変数publicとprivateについて、変数countryの値ごとに水平方向の積み上げ棒グラフを描画（描画順は変数totalの値でソート）
graph hbar (asis) public private, over(country, sort(total) descending) stack title( "Spending on tertiary education as % of GDP, 1999", span pos(11) ) subtitle(" ") note("Source: OECD, Education at a Glance 2002", span)

コピー

*サンプルデータを読み込み
use https://www.stata-press.com/data/r17/educ99gdp, clear
*変数privateとpublicから新規変数fracを作成
generate frac = private/(private + public)
*変数publicとprivateについて、変数countryの値ごとに水平方向の100%積み上げ棒グラフを描画（描画順は変数fracの値でソート）
graph hbar (asis) public private, over(country, sort(frac) descending) stack percent title("Public and private spending on tertiary education, 1999", span pos(11) ) subtitle(" ") note("Source: OECD, Education at a Glance 2002", span)

コピー

*サンプルデータを読み込み
webuse sp500, clear
*y変数をchange、x変数をdateとして二元ドロップライングラフを描画（観測値の範囲は1～57行目）
twoway dropline change date in 1/57

コピー

*サンプルデータを読み込み
webuse gnp96, clear
*y変数をgnp96の階差、x変数をdateとして水平方向の二元ドロップライングラフを描画（観測値の範囲は1～71行目）
twoway dropline d.gnp96 date in 1/71, horizontal

コピー

*サンプルデータを読み込み
webuse sp500, clear
*y変数をchange、x変数をdateとして二元スパイクプロットを描画（観測値の範囲は1～57行目）
twoway spike change date in 1/57

コピー

*サンプルデータを読み込み
webuse census, clear
*変数popについて、変数regionの値によって円グラフを描画
graph pie pop, over(region)

コピー

*サンプルデータを読み込み
webuse census, clear
*変数popについて、変数regionの値によって切り出し円グラフを描画
graph pie pop, over(region) pie(1,explode) pie(2,explode) pie(3,explode) pie(4,explode)

コピー

*現在のデータセットをクリア
clear
*4つの変数と観測値を入力
input sales marketing research development
12 14 2 8
end
*各変数のラベルを定義
label var sales "Sales"
label var market "Marketing"
label var research "Research"
label var develop "Development"
*変数salesとmarketingとresearchとdevelopmentについてラベル付き円グラフを描画
graph pie sales marketing research development, plabel(_all name, size(*1.5) color(white)) legend(off) plotregion(lstyle(none)) title("Expenditures, XYZ Corp.") subtitle("2002") note("Source: 2002 Financial Report (fictional data)")

コピー

*サンプルデータを読み込み
webuse census, clear
*変数popについて、変数regionの値によって円グラフを描画（一部を切り出してパーセンテージラベルを付加）
graph pie pop, over(region) pie(2,explode) plabel(2 percent)

コピー

*サンプルデータを読み込み
webuse nlsw88, clear
*変数wageについて、変数occupationの値ごとにドットチャートを描画
graph dot wage, over(occ)

コピー

*サンプルデータを読み込み
webuse nlsw88, clear
*変数wageとhoursについて、変数occupationの値ごとにドットチャートを描画
graph dot wage hours, over(occ)

コピー

*サンプルデータを読み込み
webuse nlsw88, clear
*変数wageとhoursとttl_expについて、変数occupationの値ごとにドットチャートを描画
graph dot wage hours ttl_exp, over(occ)

コピー

*サンプルデータを読み込み
use https://www.stata-press.com/data/r17/sp500, clear
*変数volumeについてヒストグラムを描画
histogram volume

コピー

*サンプルデータを読み込み
use https://www.stata-press.com/data/r17/auto, clear
*変数mpgについてラベル付きヒストグラムを描画
histogram mpg, discrete freq addlabels ylabel(,grid) xlabel(12(2)42)

コピー

*サンプルデータを読み込み
webuse sp500, clear
*変数openについてヒストグラムとカーネル密度推定曲線を描画
histogram open, frequency kdensity

コピー

*サンプルデータを読み込み
webuse sp500, clear
*変数openについてヒストグラムと正規密度曲線を描画
histogram open, frequency normal

コピー

*サンプルデータを読み込み
webuse hospdd, clear
*変数satisについて変数procedureの値ごとにヒストグラムを作成し、2つのグラフを並べる
histogram satis, by(procedure)

コピー

*サンプルデータを読み込み
webuse hospdd, clear
*変数satisについて変数procedureの値ごとにヒストグラムを作成し、透過して重ねる
twoway (histogram satis if procedure == 0, color(blue%30))  (histogram satis if procedure == 1, color(red%30)), legend(order(1 "Old" 2 "New"))

コピー

*ユーザ作成コマンドbinhistをインストール
ssc install bihist
*サンプルデータを読み込み
webuse hospdd, clear
*変数satisについて変数procedureの値ごとにヒストグラムを作成し、垂直方向に反転して並べる
bihist satis, by(procedure)

コピー

*サンプルデータを読み込み
webuse lbw,clear
*変数ageの値の範囲を確認（ヒストグラムのスケールとビンの幅を検討するため）
codebook age
*変数ageについて、変数smokeの値が0のケースのヒストグラムを作成
histogram age if smoke==0, width(5) start(10) percent color(blue%30)horizontal yscale(range(5 50)) ylabel(, nogrid) xscale(reverse) xlabel(, grid) xline(0, lcolor(black)) title(Non-smoker) legend(off) name(his1, replace) plotregion(margin(zero) ilcolor(black))
*変数ageについて、変数smokeの値が1のケースのヒストグラムを作成
histogram age if smoke==1, width(5) start(10) percent color(red%30)horizontal yscale(off) yscale(range(5 50)) ylabel(, nogrid) xlabel(, grid) xline(0, lcolor(black)) title(Smoker) legend(off) name(his2, replace) plotregion(margin(zero) ilcolor(black))
*2つのグラフを統合
graph combine his1 his2, imargin(zero)

コピー

*サンプルデータを読み込み
webuse hospdd, clear
*変数satisについて変数procedureの値ごとにヒストグラムを作成し、水平方向に並べる
histogram satis, percent fcolor(%60) horizontal ylabel(, nogrid) xline(0, lcolor(black)) xlabel(, grid) by(procedure, imargin(zero)) graphregion(margin(zero)) plotregion(margin(zero))
*グラフエディタを使用して一方のX軸スケールを反転させる

コピー
グラフエディタで編集

*サンプルデータを読み込み
webuse bplong, clear
*変数bpについて、変数agegrpの値ごとに箱ひげ図を描画
graph box bp, over(agegrp)

コピー

*サンプルデータを読み込み
webuse bpwide, clear
*変数bp_beforeとbp_afterについて箱ひげ図を描画
graph box bp_before bp_after

コピー

*サンプルデータを読み込み
use https://www.stata-press.com/data/r17/bplong, clear
*変数bpについて、変数whenとsexの値ごとに箱ひげ図を描画
graph box bp, over(when) over(sex)  ytitle("Systolic blood pressure")  title("Response to Treatment, by Sex")  subtitle("(120 Preoperative Patients)" " ") note("Source: Fictional Drug Trial, StataCorp, 2003")

コピー

*サンプルデータを読み込み
use https://www.stata-press.com/data/r17/nlsw88, clear
*変数wageについて、変数indの値ごとに水平方向の箱ひげ図を描画
graph hbox wage, over(ind, sort(1)) nooutside ytitle("") title("Hourly wage, 1988, woman aged 34-46", span) subtitle(" ") note("Source: 1988 data from NLS, U.S. Dept of Labor, Bureau of Labor Statistics", span) 

コピー

*サンプルデータを読み込み
webuse bpwide, clear
*変数bp_beforeとbp_afterについて、中央値のシンボルを表示した箱ひげ図を描画
graph box bp_before bp_after, medtype(marker) medmarker(msymbol(diamond))

コピー

*サンプルデータを読み込み
webuse auto, clear
*変数priceについて対称プロットを描画
symplot price

コピー

*サンプルデータを読み込み
webuse auto, clear
*変数mpgについて各べき乗による変数変換後のヒストグラムを描画
gladder mpg, fraction

コピー

*サンプルデータを読み込み
webuse citytemp, clear
*変数heatddについて各べき乗による変数変換後の正規分布分位点プロットを描画
qladder heatdd

コピー

*サンプルデータを読み込み
webuse nlsw88, clear
*変数ageについてスパイクプロットを描画
spikeplot age

コピー

*サンプルデータを読み込み
webuse auto, clear
*変数priceについて分位点プロットを描画
quantile price

コピー

*サンプルデータを読み込み
webuse auto, clear
*変数priceについて正規分位点プロットを描画
qnorm price

コピー

*サンプルデータを読み込み
webuse auto, clear
*変数priceについて標準正規確率プロットを描画
pnorm price

コピー

*サンプルデータを読み込み
webuse auto, clear
*変数priceとmpgを標準化し、新規変数c1とc2を作成
egen c1 = std(price)
egen c2 = std(mpg)
*変数c1とc2から新規変数chを作成
generate ch = c1^2 + c2^2
*変数chについてカイ二乗分位点プロットを描画
qchi ch, df(2)

コピー

*サンプルデータを読み込み
webuse auto, clear
*変数priceとmpgを標準化し、新規変数c1とc2を作成
egen c1 = std(price)
egen c2 = std(mpg)
*変数c1とc2から新規変数chを作成
generate ch = c1^2 + c2^2
*変数chについてカイ二乗確率プロットを描画
pchi ch, df(2)

コピー

*サンプルデータを読み込み
webuse auto, clear
*変数weightから変数foreignの値によって新規変数weightdとweightfを作成
generate weightd = weight if !foreign
generate weightf = weight if foreign
*変数weightdとweightfについてQ-Qプロットを描画
qqplot weightd weightf

コピー

*サンプルデータを読み込み
webuse auto, clear
*変数mpgとdisplについてサンフラワープロットを描画
sunflower mpg displ

コピー

*サンプルデータを読み込み
use https://www.stata-press.com/data/r17/auto, clear
*変数weightとlengthについて、散布図、局所多項スムージング曲線、Lowessスムージング曲線を描画
twoway scatter weight length, mcolor(*.6) || lpoly weight length || lowess weight length 

コピー

*サンプルデータを読み込み
use https://www.stata-press.com/data/r17/auto, clear
*変数mpgとweightについて、散布図、局所線形スムージング線、Lowessスムージング曲線を描画
twoway scatter mpg weight, mcolor(*.6) || lfit mpg weight || lowess mpg weight

コピー

*サンプルデータを読み込み
use https://www.stata-press.com/data/r17/fishdata, clear
*変数freqに対してロバスト非線形スムージングを実行し、結果を新規変数sfreqに保存
smooth 4253eh,twice freq, gen(sfreq)
*y変数をfreq、x変数をlengthとして散布図を描画し、ロバスト非線形スムージング曲線を重ね描き
scatter sfreq freq length, c(l .) m(i o) title("Smoothed frequencies of fish lengths") ytitle("") xlabel(#4)

コピー

*サンプルデータを読み込み
use https://www.stata-press.com/data/r17/lifeexp, clear
*変数lexpについてヒストグラムを描画し、カーネル密度スムージング曲線を重ね描き
twoway histogram lexp, color(*.5) || kdensity lexp

コピー