Stata グラフギャラリー　解析のグラフ

Stataでは、様々なグラフを作成することができます。統計解析の結果を表示するためのグラフと、作成コマンドをまとめました。

ROC曲線
回帰フィット
生存曲線
時系列グラフ
メタ分析
VAR、VEC
多変量グラフ
サンキーダイアグラム

ワンポイントアドバイスコマンドの実行方法

コピーボタンをクリックして、Stataのコマンドウィンドウにコマンドを貼りつけし、Enterキーを押すとサンプルグラフが作成できます。
※旧バージョンでは、一部未対応の可能性があります。最新バージョンでお試しください。

基本のグラフはこちら

ROC曲線

ROC曲線は、連続の独立変数の比較やカットオフ値の設定に使用されます。
x軸に儀陽性率、y軸に感度をプロットし、診断の精度を比較したり最適なカットオフ値を決定します。

疫学統計の詳細は、下記ページをご覧ください。

疫学

医療研究に役立つ機能

ROC曲線A

ノンパラメトリック法によるROC曲線


webuse hanley, clear
roctab disease rating, graph

ROC曲線B

パラメトリック法によるROC曲線


webuse hanley, clear
rocfit disease rating
rocplot, confband

ROC曲線C

lorenzオプションを使用してローレンツ曲線をプロットし、Gini曲線とPietra指数を示します。


webuse lorenz, clear
roctab disease class [fweight=pop], lorenz graph

ROC曲線D

AUCを比較します。


webuse ct, clear
roccomp status mod1 mod2, graph

ROC曲線E

ゴールドスタンダードのROC曲線に対してAUCを比較します。


webuse ct2, clear
rocgold status mod1 mod2 mod3, graph

回帰フィット

回帰フィットプロットは、元のデータポイントの散布図に、フィット曲線を重ね描きする形式が一般的によく利用されます
フィット曲線は、最小二乗法によって推定されます
信頼区間の描画や、カテゴリごとのフィット結果の比較も簡単に行えます

線形予測

線形予測A

y=ax+bの線形（直線）予測。フィット線のみ描画されます。


webuse auto, clear
twoway lfit mpg weight

線形予測B

データポイントの散布図とフィット線をプロットします。


webuse auto, clear
twoway scatter mpg weight || lfit mpg weight

線形予測C

カテゴリ変数の値ごとにグラフを作成し、合計のフィット結果もグラフ化します。


webuse auto, clear
twoway scatter mpg weight || lfit mpg weight ||, by(foreign, total row(1))

線形予測D

フィット線と信頼区間をプロットします。


webuse auto, clear
twoway lfitci mpg weight

線形予測E

データポイントの散布図、フィット線、信頼区間をプロットします。


webuse auto, clear
twoway lfitci mpg weight || scatter mpg weight

フラクショナル多項式

xのフラクショナル多項式の推定からyの予測を計算します。

フラクショナル多項式A

フィット曲線のみをプロットします。


webuse auto, clear
twoway fpfit mpg weight

フラクショナル多項式B

データポイントの散布図とフィット曲線をプロットします。


webuse auto, clear
twoway scatter mpg weight || fpfit mpg weight

フラクショナル多項式C

カテゴリ変数の値ごとにグラフを作成し、合計のフィット結果もグラフ化します。


webuse auto, clear
twoway scatter mpg weight || fpfit mpg weight ||, by(foreign, total row(1))

フラクショナル多項式D

フィット曲線と信頼区間をプロットします。


webuse auto, clear
twoway fpfitci mpg weight

フラクショナル多項式E

データポイントの散布図、フィット曲線、信頼区間をプロットします。


webuse auto, clear
twoway fpfitci mpg weight || scatter mpg weight

二次フィット

xおよびx^2でのyの回帰から、yの予測を計算します。

二次フィットA

フィット曲線のみをプロットします。


webuse auto, clear
twoway qfit mpg weight

二次フィットB

データポイントの散布図とフィット曲線をプロットします。


webuse auto, clear
twoway scatter mpg weight || qfit mpg weight

二次フィットC

カテゴリ変数の値ごとにグラフを作成し、合計のフィット結果もグラフ化します。


webuse auto, clear
twoway scatter mpg weight || qfit mpg weight ||, by(foreign, total row(1))

二次フィットD

フィット曲線と信頼区間をプロットします。


webuse auto, clear
twoway qfitci mpg weight

二次フィットE

データポイントの散布図、フィット曲線、信頼区間をプロットします。


webuse auto, clear
twoway qfitci mpg weight || scatter mpg weight

生存曲線

生存分析は、イベント（死亡や故障）が発生するまでの時間や影響する因子を分析する手法で、主に医療分野でよく使われます

ここでは、死亡率（故障率）、Kaplan–Meier生存曲線、Nelson–Aalen累積ハザード関数、生命表、Cox 比例ハザードモデルの描き方を紹介します

サンプル中のstsetコマンドは、生存時間データを設定するコマンドです。詳細は下記ページをご覧ください。例題を解説したダウンロード資料もご用意しております。

生存分析

死亡率（故障率）

死亡率（故障率）A

推定された死亡率とその信頼区間をプロットします。


webuse cancer, clear
stset studytime, failure(died)
strate drug, graph

死亡率（故障率）B

死亡率のみをプロットします。


webuse cancer, clear
stset studytime, failure(died)
strate drug, graph nowhisker

死亡率（故障率）C

推定された死亡率とその信頼区間をプロットします。死亡率のプロットを直線でつなぎ、信頼区間のプロットにキャップを付けるオプションを適用しています。


webuse cancer, clear
stset studytime, failure(died)
strate drug, graph recast(connected) ciopts(recast(rcap))

Kaplan–Meier生存曲線

生存確率（イベント発生確率）の時間変化を調べます。

Kaplan–Meier生存曲線A

x軸を時間、ｙ軸を生存確率とし、生存確率の時間変化をプロットします。


webuse stan3, clear
sts graph

Kaplan–Meier生存曲線B

共変量ごとに生存曲線をプロットします。


webuse stan3, clear
sts graph, by(posttran)

Kaplan–Meier生存曲線C

各時間のリスクにさらされている数（観察対象の数）を表記するオプションです。打ち切り（lost）や、遅延組入と打ち切り（enter）を表記するオプションなどもご利用いただけます。


webuse drug2, clear
sts graph, atrisk

Kaplan–Meier生存曲線D

Kaplan–Meier生存曲線と各プロットの95％信頼区間を表示します。


webuse stan3, clear
sts graph, by(posttran) ci

Nelson–Aalen累積ハザード関数

死亡確率の時間変化を調べます。

Nelson–Aalen累積ハザード関数A

cumhaz オプション（またはnaオプション）を使用してNelson–Aalen累積ハザード関数をプロットします。


webuse stan3, clear
sts graph, na

Nelson–Aalen累積ハザード関数B

共変量ごとに累積ハザード関数をプロットします。


webuse stan3, clear
sts graph, na by(posttran)

Nelson–Aalen累積ハザード関数C


webuse stan3, clear
sts graph, na atrisk

生命表

年齢別死亡率が変化しないと仮定した際の、生存者数や死亡率の時間変化です。

生命表A

x軸に時間、y軸に生存率をプロットします。


webuse tumor, clear
ltable t d, survival graph

生命表B

noconfオプション（信頼区間なし）を使用します。


webuse tumor, clear
ltable t d, survival graph noconf

生命表C

共変量ごとに生命表をプロットします。


webuse cancer, clear
ltable studytime died, by(drug) noconf graph overlay

Cox 比例ハザードモデル

説明変数がハザード関数に影響を及ぼしているか否かを調べます。

Cox 比例ハザードモデルA

Coxモデルを適用した後に、stcurveコマンドでグラフ化します。at((zero) _all)オプションを使って、全ての共変量を0に設定したベースライン生存曲線を描画しています。


webuse idu, clear
stintcox age_mean i.male i.needle i.inject i.jail, interval(ltime rtime)
stcurve, survival at((zero) _all)

Cox 比例ハザードモデルB

atオプションで共変量を任意の値に設定して生存関数をプロットします。


webuse idu, clear
stintcox age_mean i.male i.needle i.inject i.jail, interval(ltime rtime)
stcurve, survival at(male=(0 1))

時系列グラフ

時系列モデルとグラフコマンドをご紹介します

お手持ちのデータで操作してエラーが出る場合は、データを時系列データとして設定する必要があります。メニューの統計＞時系列＞セットアップとユーティリティ＞時系列データのセットアップ（またはtssetコマンド）で設定できます。
時系列分析の詳細は、下記ページをご覧ください。例題を解説したダウンロード資料もご用意しております。

時系列分析

コレログラムA

自己相関を表すコレログラムを作成します。lags()オプションでラグを指定します。


webuse air2, clear
ac air, lags(20)

コレログラムB

偏自己相関をグラフで表示します。lags()オプションでラグを指定します。


webuse air2, clear
pac air, lags(20)

コレログラムC

DS.オペレータを変数名に追加して、季節性とトレンドを制御した偏自己相関をグラフにします。


webuse air2, clear
pac DS12.air, lags(20)

クロスコレログラム

2変数のクロスコレログラムを作成します。lags()オプションでラグを指定します。xline()オプションで基準線を追加しています。


webuse furnace, clear
xcorr input output, xline(5) lags(40)

ピリオドグラムA

系列の対数標準化したピリオドグラムを作成します。


webuse air2, clear
pergram air

ピリオドグラムB

ピリオドグラムを0を基準に塗りつぶし、範囲グラフとして表示します。


webuse air2, clear
pergram air, recast(area)

ピリオドグラムC

系列がホワイトノイズに従うかを検定する、Bartlettのピリオドグラム検定を行い、結果をグラフで表示します。


webuse tsappend1, clear
wntestb x in 1/100

累積スペクトルA

時系列の累積サンプルスペクトル分布をグラフで表示します。


webuse cos4, clear
cumsp sumfc

累積スペクトルB

時系列の累積サンプルスペクトル分布をグラフで表示し、xline()で基準線を追加します。


webuse air2, clear
cumsp air, xline(.08333)

累積スペクトルC

時系列の累積サンプルスペクトル分布をグラフで表示し、折れ線から範囲グラフに変更して表示します。


webuse cos4, clear
cumsp sumfc, recast(area)

時系列グラフA

x軸を時間として、系列を折れ線グラフにします。


webuse tsappend1, clear
tsline y

時系列グラフB

x軸を時間として、複数の系列を折れ線グラフにし、オーバーレイします。


webuse tsappend1, clear
tsrline y e

時系列グラフC

x軸を時間として、系列の折れ線グラフにマーカーを追加します。


webuse tsappend1, clear
tsline y, recast(connected)

時系列グラフD

x軸を時間として、系列データを散布点で表示します。


webuse tsappend1, clear
tsline y, recast(scatter)

メタ分析

メタ分析は、複数の研究結果を統合し、研究全体の推定値を得る解析方法です
フォレストプロット、ファンネルプロット、L’Abb ́eプロット、バブルプロット、ガルブレイスプロットを紹介します

メタ分析の詳細は、下記ページをご覧ください。例題を解説したダウンロード資料もご用意しております。

メタ分析

フォレストプロットA

メタ分析の結果を表します。デフォルトでは対数リスク比が表示されます。オプションで、リスク比（rr）やオッズ比（or）表示にすることができます。


use https://www.stata-press.com/data/r17/bcgset, clear
meta forestplot

フォレストプロットB

サブグループごとにフォレストプロットを表示します。


use https://www.stata-press.com/data/r17/bcgset, clear
meta forestplot, subgroup(alloc)

フォレストプロットC

leave-one-outメタ分析のフォレストプロットです。リスク比オプションも使用しています。


use https://www.stata-press.com/data/r17/bcgset, clear
meta forestplot, leaveoneout rr

ファンネルプロット

ｘ軸に各研究の効果量、ｙ軸に各研究の精度を表します。出版バイアスがない場合、左右対称の漏斗型になります。


use https://www.stata-press.com/data/r17/nsaidsset, clear
meta funnelplot

L’Abb ́eプロット

2つのグループの二値アウトカムを比較します。異質性を評価し、2つのグループで研究固有のイベント率を比較します。


use https://www.stata-press.com/data/r17/bcgset, clear
meta labbeplot, legend(cols(1) symxsize(*0.6) position(10) ring(0))

バブルプロット

共変量（x軸）と効果量（y軸）の散布図です。効果量の有為性が高い程大きな円となります。


meta regress latitude_c
estat bubbleplot

ガルブレイスプロット

メタ分析の結果を要約します。研究それぞれの固有の効果量とその精度、全体的な効果量を表示し、潜在的な外れ値を検出します。効果量間の異質性を評価する助けにもなります。


use https://www.stata-press.com/data/r17/bcgset, clear
meta galbraithplot

VAR、VEC

VARモデルは、各従属変数の多変量時系列回帰を、目的変数のラグおよび他のすべての従属変数のラグに適合させます
VECモデルは、最尤法を使用して、いくつかの変数が共和分される一種のベクトル自己回帰に適合します

VAR・VECモデルA

VECモデルを推定後、予測グラフを出力します


use https://www.stata-press.com/data/r17/urates, clear
vec missouri indiana kentucky illinois if t < tm(2003m7), trend(rconstant) rank(2) lags(4)
fcast compute m1_, step(6)
fcast graph m1_missouri m1_indiana m1_kentucky m1_illinois, observed

VAR・VECモデルB

インパルス変数とレスポンス変数を指定して、IRF分析を行います。


use https://www.stata-press.com/data/r17/lutkepohl2, clear
mat a = (., 0, 0\0,.,0\.,.,.)
mat b = I(3)
svar dln_inv dln_inc dln_consump, aeq(a) beq(b)
irf create modela, set(results3) step(8)
svar dln_inc dln_inv dln_consump, aeq(a) beq(b)
irf create modelb, step(8)
irf graph oirf sirf, impulse(dln_inc) response(dln_consump)

VAR・VECモデルC

FEVD分析を行います。


use https://www.stata-press.com/data/r17/lutkepohl2, clear
mat a = (., 0, 0\0,.,0\.,.,.)
mat b = I(3)
svar dln_inv dln_inc dln_consump, aeq(a) beq(b)
irf create modela, set(results3) step(8)
svar dln_inc dln_inv dln_consump, aeq(a) beq(b)
irf create modelb, step(8)
irf graph fevd sfevd, impulse(dln_inc) response(dln_consump) lstep(1) legend(cols(1))

VAR・VECモデルD

IRF分析のグラフを重ね合わせて表示します


use https://www.stata-press.com/data/r17/lutkepohl2, clear
var dln_inv dln_inc dln_consump if qtr<=tq(1978q4), lags(1/2) dfk
irf create order1, step(10) set(myirf1, new)
irf create order2, step(10) order(dln_inc dln_inv dln_consump)
irf ograph (order1 dln_inc dln_consump oirf) (order2 dln_inc dln_consump oirf)

VAR・VECモデルE

VECモデルを推定後、安定条件を確認します。


webuse rdinc, clear
vec ln_ne ln_se
vecstable, graph

多変量グラフ

多変量解析は、複数の変数に関して相互の関連などを調べる手法です。

多変量解析の詳細は、下記ページをご覧ください。

多変量解析

多変量グラフA

クラスター分析を行ったあと、樹形図を描画します。上図はデンドログラムという樹形図を出力します。


use https://www.stata-press.com/data/r17/labtech, clear
cluster completelinkage x1 x2 x3 x4, name(L2clnk)
cluster dendrogram L2clnk, labels(labtech) xlabel(, angle(90) labsize(*.75))

多変量グラフB

バイプロットは、観測値（行）と変数の相対位置（列）を同時に表示します。


use https://www.stata-press.com/data/r17/renpainters, clear
biplot composition-expression, alpha(1) stretch(10) table rowopts(name(Painters)) rowlabel(painter) colopts(name(Attributes)) title(Renaissance painters)

サンキーダイアグラム

サンキーダイアグラムとは、工程間の流量を表現します。

adoファイルsankey_plotを利用します。まずは「ssc install sankey_plot」を実行し、インストールします。

サンキーダイアグラムA

2段階の工程を持つサンキーダイアグラム


*サンプルデータを読み込み
use http://fmwww.bc.edu/repec/bocode/i/immigration.dta, clear
*始点の座標がx0とfrom、終点がx1とtoという変数で指定し、接続線の太さをwidth0()オプションで指定
sankey_plot x0 from x1 to, width0(value) extra adjust fillcolor(%50) noline xlabel(1 "Source" 2 "Destination", nogrid)

サンキーダイアグラムB

3段階の工程を持つサンキーダイアグラム


*サンプルデータを読み込み
use http://fmwww.bc.edu/repec/bocode/d/dogs_and_happiness.dta, clear
sankey_plot married pet happy , wide width(freq) fillcolor(%50) xlabel("",nogrid) gap(0.1)

Stata グラフギャラリー 解析のグラフ

ワンポイントアドバイスコマンドの実行方法

ROC曲線

ROC曲線A

ROC曲線B

ROC曲線C

ROC曲線D

ROC曲線E

回帰フィット

線形予測

線形予測A

線形予測B

線形予測C

線形予測D

線形予測E

フラクショナル多項式

フラクショナル多項式A

フラクショナル多項式B

フラクショナル多項式C

フラクショナル多項式D

フラクショナル多項式E

二次フィット

二次フィットA

二次フィットB

二次フィットC

二次フィットD

二次フィットE

生存曲線

死亡率（故障率）

死亡率（故障率）A

死亡率（故障率）B

死亡率（故障率）C

Kaplan–Meier生存曲線

Kaplan–Meier生存曲線A

Kaplan–Meier生存曲線B

Kaplan–Meier生存曲線C

Kaplan–Meier生存曲線D

Nelson–Aalen累積ハザード関数

Nelson–Aalen累積ハザード関数A

Nelson–Aalen累積ハザード関数B

Nelson–Aalen累積ハザード関数C

生命表

生命表A

生命表B

生命表C

Cox 比例ハザードモデル

Cox 比例ハザードモデルA

Cox 比例ハザードモデルB

時系列グラフ

コレログラムA

コレログラムB

コレログラムC

クロスコレログラム

ピリオドグラムA

ピリオドグラムB

ピリオドグラムC

累積スペクトルA

累積スペクトルB

累積スペクトルC

時系列グラフA

時系列グラフB

時系列グラフC

時系列グラフD

メタ分析

フォレストプロットA

フォレストプロットB

フォレストプロットC

ファンネルプロット

L’Abb ́eプロット

バブルプロット

ガルブレイスプロット

VAR、VEC

VAR・VECモデルA

VAR・VECモデルB

VAR・VECモデルC

VAR・VECモデルD

VAR・VECモデルE

多変量グラフ

多変量グラフA

多変量グラフB

Stata グラフギャラリー　解析のグラフ